PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Alexander F Rødseth <xyproto@archlinux.org>
# Contriutor (Arch): Eric Belanger <eric@archlinux.org>
# Contributor (Arch): Jo Christian Bergskås <jcberg@gmail.com>

# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
# Arch version uses git

pkgname=fceux
pkgver=2.6.1
pkgrel=1
url='https://fceux.com/'
pkgdesc='Fast and ultra-compatible NES/Famicom emulator'
arch=(x86_64)
license=(GPL)
depends=(gd lua minizip qt5-base sdl2)
makedepends=(cmake glu mesa-libgl ninja)
optdepends=('ffmpeg: for recording')
source=("https://github.com/TASVideos/${pkgname}/archive/${pkgname}-${pkgver}.tar.gz")
b2sums=('ffec010d38b188b7d7cce44ef78b7a88021d16e14373932c54a8aff9e799b5ddd4dddc59cc823c771acd49b732e4b3e263d66343306eaea3761c39de14c9e78a')

build() {
  cd ${pkgname}-${pkgname}-${pkgver}

  export CFLAGS="$CFLAGS -O3 -flto=auto -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -flto=auto -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

  mkdir -p build
  cd build

  cmake .. \
  -DCMAKE_INSTALL_PREFIX=/usr \
  -G Ninja
  ninja
}

package() {
  cd ${pkgname}-${pkgname}-${pkgver}
  DESTDIR="$pkgdir" ninja -C build install

  install -d "${pkgdir}/usr/share/doc/${pkgname}"
  cp -r ${srcdir}/${pkgname}-${pkgname}-${pkgver}/documentation/* "${pkgdir}/usr/share/doc/${pkgname}/"
  install -Dm644 ${srcdir}/${pkgname}-${pkgname}-${pkgver}/changelog.txt "${pkgdir}/usr/share/doc/${pkgname}/"
}