blob: 93c6ae42f56ef2690d9c0ae5e8928d3dfef8fecd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# # I maintain this because:
# Arch version uses gtk
# Arch version uses http
# Arch version lacks additional optimization and hardening flags
_pkgname=freeciv
pkgname=freeciv-qt
pkgver=3.2.0
pkgrel=1
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64' 'aarch64')
url="http://www.freeciv.org/"
license=('GPL')
options=('lto')
depends=('qt6-base' 'sdl2_mixer' 'lua' 'sqlite' 'curl')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.xz)
sha512sums=('03d4bdf0bece4858c5ab802fc54fa6b58cf72b5526baef04642aff4f048210304629cfe416f4d2c8550f234c563c21ab83af5f8e77bb50fc9f9b17ab8f9e21ce')
b2sums=('3ff24f0051208b69accf46a1647882f06148777deb9ef42381970a12a332f3d7eb4c6d298bc04f7c0dffebec8ad04ec6213e91abb3f2d9b8f0679077df0bca9a')
build() {
cd ${_pkgname}-${pkgver}
export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIC"
export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIC"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--enable-shared \
--enable-sys-lua \
--enable-client=qt \
--enable-fcmp=qt \
--enable-fcdb=sqlite3 \
--enable-aimodules
make
}
package() {
cd ${_pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
}
|
