blob: 43209ca055d06c42b0a8a01f0efca4940edc550e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Eric Bélanger <eric@archlinux.org>
# # I maintain this because:
# Arch version uses gtk
# Arch version uses http
# Arch version lacks additional optimization and hardening flags
_pkgname=freeciv
pkgname=freeciv-qt
pkgver=2.6.2
pkgrel=2
pkgdesc="A multiuser clone of the famous Microprose game of Civilization"
arch=('x86_64' 'aarch64')
url="https://www.freeciv.org/"
license=('GPL')
depends=('qt5-base' 'sdl2_mixer' 'lua53' 'sqlite' 'curl')
makedepends=('python')
conflicts=('freeciv')
provides=('freeciv')
backup=('etc/freeciv/database.lua')
source=(https://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.bz2
qt5.15-fix.diff)
b2sums=('5d30274f24786dcd0b29d4d85a45be47e791aedba7fbeeb28001e2c19d2acc1fa16b4ab88b779d0dbd318806e571a26c94f8a61b33c6d8df8e68d4fd90713302'
'bd56898fa81f1e6fa68e3b47de124f5033ac9f20488bb9d128e3f7ec6b83e690293287f3b7f95b8e16f75787428e7351f1d6b89ec4c459c525655320b72f7732')
prepare() {
cd ${_pkgname}-${pkgver}
#workaround for qt 5.15
patch -p1 -i ${srcdir}/qt5.15-fix.diff
}
build() {
cd ${_pkgname}-${pkgver}
export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
./configure --prefix=/usr --sysconfdir=/etc --enable-shared --enable-sys-lua \
--enable-client=qt --enable-fcmp=qt --enable-fcdb=sqlite3 --enable-aimodules
make
}
package() {
cd ${_pkgname}-${pkgver}
make DESTDIR="${pkgdir}" install
}
|
