PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): David A. Redick <david.a.redick@gmail.com>
# Contributor (AUR): Petteri Tolonen <petteri dot tolonen at gmail dot com>

# # I maintain this because:
# AUR version uses ftp

pkgname=freedink
pkgver=109.6
pkgrel=1
url='https://www.gnu.org/software/freedink/'
pkgdesc='Humorous top-down adventure and role-playing game.'
arch=('x86_64')
license=('GPL3')
depends=('freedink-data' 'libzip' 'bzip2' 'zlib' 'fontconfig' 'freetype2'
         'sdl2_image' 'sdl2_mixer' 'sdl2_ttf' 'sdl2_gfx' 'sdl2' 'expat'
         'libutil-linux' 'libpng' 'harfbuzz' 'glib2' 'graphite' 'pcre')
makedepends=('automake' 'autoconf' 'check' 'help2man' 'make' 'cxxtest' 'glm' 'xorg-server-xvfb')
source=("https://ftp.gnu.org/gnu/freedink/${pkgname}-${pkgver}.tar.gz")
sha512sums=('9de4155e65c1af58166e30f3f642fed2111eeff2cfccedcd51ea7715e91795d9c9f89d4fa30a801e9a998b7d734682b7d2588ef1ebaba464764c3c3156b6a7ad')

build () {
	cd "${srcdir}/${pkgname}-${pkgver}"
	./configure --prefix=/usr
	make
}

check () {
	cd "${srcdir}/${pkgname}-${pkgver}"

	# This is just a trivial check.
	xvfb-run -a -n 96 -s "-screen 0 1600x1200x24" make check

	# This for the packaging of the source code in a snap shot package
	# NOT the installed build artifacts.
	#make distcheck
}

package () {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install
}