PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Luis Martinez <luis dot martinez at disroot dot org>
# Contributor (AUR): Caltlgin Stsodaat <contact@fossdaily.xyz>
# Contributor (AUR): Sandy Carter <bwrsandman+aur@gmail.com>

# # I maintain this because:
# Arch lacks this package and vcmi relies on it
# Aur version build fails with Werror

pkgname=fuzzylite
pkgver=6.0
pkgrel=3
pkgdesc='C++ fuzzy logic control library'
arch=('x86_64' 'i686' 'aarch64')
url='https://github.com/fuzzylite/fuzzylite'
license=('GPL3')
depends=('gcc-libs')
makedepends=('cmake')
provides=('libfuzzylite.so=6.0-64')
changelog=CHANGELOG
source=("$pkgname-$pkgver.tar.gz::https://github.com/fuzzylite/fuzzylite/archive/v$pkgver.tar.gz")
sha256sums=('7e9f56deb9baf063de2232bfd8285f57ddccb651dae842fe3f587d0ac65ecdb0')

prepare() {

  sed \
    -e 's/-Werror//' \
    -i $pkgname-$pkgver/$pkgname/CMakeLists.txt

}

build() {
  cmake \
    -B build \
    -S "$pkgname-$pkgver/$pkgname" \
    -DCMAKE_BUILD_TYPE='None' \
    -DCMAKE_INSTALL_PREFIX='/usr' \
    -DFL_BUILD_STATIC=OFF \
    -DFL_BUILD_TESTS=OFF \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install
  cd "$pkgname-$pkgver"
  install -Dm644 -t "$pkgdir/usr/share/doc/$pkgname" 'README.md'
  install -Dm644 -t "$pkgdir/usr/share/man/man1" "$pkgname/$pkgname.1"
}