PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

pkgname=gradm
_version=3.1
_timestamp=201708012022
pkgver=$_version.$_timestamp
pkgrel=1
pkgdesc="Administration utility for grsecurity's Role Based Access Control (RBAC)"
arch=(i686 x86_64)
url=https://grsecurity.net/
license=(GPL2)
depends=(pam)
source=(https://iserlohn-fortress.net/downloads/unofficial_grsec-libre/${pkgname}-${_version}-${_timestamp}.tar.gz{,.sig}
#source=(https://grsecurity.net/stable/${pkgname}-${_version}-${_timestamp}.tar.gz{,.sig}
        learn_config
        policy)
sha512sums=('1c319ce5b102ad54d0c4d0c43222ed755719bb2568c9a4575b62965a73b0765265dc7068488e5e34df52ed9382b17e4bf1b32a8eef20a4d7a534f3f9a4ba2b3d'
            'SKIP'
            '2fd1e94e1ea7142ee939611d58d3537d5e5842d5f6d73b8837cc9b6900fb8e34c167ab61cfcde92c045a73bb10de1c841f61a41f3f65fb9def830a81bcb4bc13'
            'a85569f7e950154cd56e1c092dc78f65d01e3f1afd067b9d5398e6bb265aeea144f3ca91f3780abab443a83432712597b9f01bfa7f2c4d7047fd2971b148f767')
validpgpkeys=(
              'DE9452CE46F42094907F108B44D1C0F82525FE49' # spender
)

prepare() {
  cd $pkgname
  sed -i -e 's/^CFLAGS :=/CFLAGS +=/' -e 's:sbin:usr/bin:' Makefile
}

build() {
  cd $pkgname
  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
  cp "$srcdir"/{learn_config,policy} "$pkgdir/etc/grsec"
  rm -r "$pkgdir/dev"
}