PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Thibaut Sautereau (thithib) <thibaut at sautereau dot fr>

# # I maintain this because:
# AUR version uses underscore
# I use it and it is not in an official repo

pkgname=hardened-malloc
_altname=hardened_malloc
pkgver=13
pkgrel=1
pkgdesc="Hardened allocator designed for modern systems"
arch=('x86_64' 'aarch64')
url="https://github.com/GrapheneOS/hardened_malloc"
license=('MIT')
depends=('gcc-libs')
makedepends=('git')
checkdepends=('python')
provides=('libhardened_malloc.so')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/GrapheneOS/hardened_malloc/archive/refs/tags/${pkgver}.tar.gz")
b2sums=('58487fda8f3480aab4b517771ae5ff5433f4ca57195a7c9e0f18622272b99342a79118e385f01b47a992f3acf209cbcdcf8c72ee183e17385d421950d2e21de6')
#validpgpkeys=('65EEFE022108E2B708CBFCF7F9E712E59AF5F22A') # Daniel Micay <danielmicay@gmail.com>

build() {
  cd "${_altname}-${pkgver}"

  make VARIANT=default
  make VARIANT=light
}

check() {
  cd "${_altname}-${pkgver}"

  make test
}

package() {
  cd "${_altname}-${pkgver}"

  install -vDm755 -t "$pkgdir/usr/lib" out/libhardened_malloc.so out-light/libhardened_malloc-light.so
  install -vDm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}