PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Ben Widawsky <ben@bwidawsk.net>
# Contributor (AUR): Isaac C. Aronson <isaac@pingas.org> (original PKGBUILD)
# Contributor (AUR): Sergio Correia <sergio@correia.cc> (modifications derived from icecream-git package)

# # I maintain this because:
# AUR version not configured for openRC
# AUR version uses excess scripts

pkgname=icecream
_exname=$pkgname-scheduler
pkgver=1.3
pkgrel=1
pkgdesc="Distributed compiler with a central scheduler to share build load"
url="https://github.com/icecc/icecream"
license=('GPL2')
makedepends=('docbook2x')
depends=('bash' 'libcap-ng' 'libarchive' 'lzo' 'zstd')
provides=('icecream')
optdepends=('icecream-sundae: A commandline monitor for Icecream'
            'icemon: Icecream GUI monitor'
            'ccache: ccache enabled remote builds.')
conflicts=('icecream-git')
backup=("etc/conf.d/$pkgname"
        "etc/conf.d/$_exname")
arch=('x86_64')
install=$pkgname.install
source=($pkgname-$pkgver.tar.gz::https://github.com/icecc/$pkgname/archive/$pkgver.tar.gz
        $pkgname.initd
        $pkgname.confd
        $_exname.initd
        $_exname.confd
        ld-$pkgname.conf)
sha256sums=('5e147544dcc557ae6f0b13246aa1445f0f244f010de8e137053078275613bd00'
            '8bacb89c6975b0f7a4411e20822d53fc2850801fb5f6ac43a0650dc245604289'
            'f667651facf89f01df61700f1fb7beef88ff4f330b4c7ca1b9ba9da9cfd2c463'
            'e65b13da1be3b4475ba765fa6dae93e009908b084d9cbc93ae2c8d4f42800ace'
            '2bf17cc1310b55270a39179a75a0732986986e8cf271f83e70f5e74ee701ec3c'
            '2221f16c3293dfd86e4d0442745b104380a4a1623ca3c9eb6bfe5771552fac65')
build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./autogen.sh
  ./configure --prefix=/usr/lib/$pkgname --enable-shared --disable-static --mandir=/usr/share/man
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install
  install -D -m755 "$srcdir"/$_exname.initd "$pkgdir/etc/init.d/$_exname"
  install -D -m644 "$srcdir"/$_exname.confd "$pkgdir/etc/conf.d/$_exname"
  install -D -m755 "$srcdir"/$pkgname.initd "$pkgdir/etc/init.d/$pkgname"
  install -D -m644 "$srcdir"/$pkgname.confd "$pkgdir/etc/conf.d/$pkgname"
  install -D -m644 "$srcdir"/ld-$pkgname.conf "${pkgdir}/etc/ld.so.conf.d/$pkgname.conf"

  # moving pkg-config file to its usual place
  install -D -m644 "${pkgdir}/usr/lib/$pkgname/lib/pkgconfig/icecc.pc" "${pkgdir}/usr/lib/pkgconfig/icecc.pc"
  rm -rf "${pkgdir}/usr/lib/$pkgname/lib/pkgconfig"
}