blob: 421687c43ff36dffc435a4a5755a995287f9a05c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer (Arch): Bruno Pagani <archange@archlinux.org>
# # I maintain this because:
# Arch version uses yubikey libs
# Arch version enables networking support
# Arch version enables update check
pkgname=keepassxc
pkgver=2.4.1
pkgrel=1
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=(GPL)
depends=(hicolor-icon-theme libgcrypt argon2 libsodium
libxtst qt5-svg qt5-x11extras
)
makedepends=(cmake qt5-tools)
source=("https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"{,.sig})
sha256sums=('0da97bd1279d1b9b06a63b9f723b43ab8c078b7f1203d6c13504fdd4735489ab'
'SKIP')
validpgpkeys=('BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2' # KeePassXC Release <release@keepassxc.org>
'3489040C1F0C3EEAB8D556A5440FC65F2E0C6E01') # Jonathan White <support@dmapps.us>
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DWITH_XC_AUTOTYPE=ON \
-DWITH_XC_NETWORKING=OFF \
-DWITH_XC_BROWSER=OFF \
-DWITH_XC_YUBIKEY=OFF \
-DWITH_XC_SSHAGENT=OFF \
-DWITH_XC_KEESHARE=OFF \
-DWITH_XC_KEESHARE_SECURE=OFF \
-DWITH_XC_UPDATECHECK=OFF
make
}
check() {
cd build
make test
}
package() {
cd build
make DESTDIR="${pkgdir}" install
}
|