PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# $Id$
# Maintainer: Balló György <ballogyor+arch at gmail dot com>

pkgname=keepassxc
pkgver=2.3.3
pkgrel=2
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64 i686)
url="https://keepassxc.org/"
license=(GPL)
depends=(hicolor-icon-theme libgcrypt argon2 libxtst qt5-x11extras)
makedepends=(cmake qt5-tools)
source=("https://github.com/keepassxreboot/$pkgname/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"{,.sig}
        "keepasspxc-2.3.3-Qt-5.11-fix.diff")
sha256sums=('cfff85ef89ba590aec798c59bea4aa3db00626d7bff8cdde0f62ee34aea60ad5'
            'SKIP'
            '5a3125f49e45127c5836d8892d056941097b4ae814f2497552871cb18c8300a8')
validpgpkeys=('BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2') # KeePassXC Release <release@keepassxc.org>

prepare() {
	mkdir -p build

	# Fix build on Qt 5.11
    patch -p0 "${srcdir}/${pkgname}-${pkgver}/src/gui/entry/EditEntryWidget.cpp" "${srcdir}/keepasspxc-2.3.3-Qt-5.11-fix.diff"
}

build() {
	cd build
	cmake ../$pkgname-$pkgver \
		-DCMAKE_BUILD_TYPE=Release  \
		-DCMAKE_INSTALL_PREFIX=/usr \
		-DCMAKE_INSTALL_LIBDIR=lib  \
		-DWITH_XC_AUTOTYPE=ON       \
		-DWITH_XC_BROWSER=OFF       \
		-DWITH_XC_HTTP=OFF          \
		-DWITH_XC_YUBIKEY=OFF       \
		-DWITH_TESTS=ON             \
		-DWITH_GUI_TESTS=OFF        \
		-DWITH_DEV_BUILD=OFF        \
		-DWITH_ASAN=OFF             \
		-DWITH_COVERAGE=OFF
	make
}

check() {
	cd build
 make test
}

package() {
	cd build
	make DESTDIR="$pkgdir" install
}