blob: 023f9408a432a58e3453a9c180a9868a3631be1a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer (Arch): Bruno Pagani <archange@archlinux.org>
# # I maintain this because:
# Arch version uses yubikey libs
# Arch version enables networking support
# Arch version enables update check
# Arch version lacks additional optimization and hardening flags
_NETBUILD=OFF
pkgname=keepassxc
pkgver=2.5.2
pkgrel=1
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=(GPL)
if [ "${_NETBUILD}" != "ON" ]; then
depends=(argon2 libgcrypt libsodium libxtst qrencode
qt5-svg qt5-x11extras
)
else
depends=(argon2 curl libgcrypt libsodium libxtst qrencode
qt5-svg qt5-x11extras quazip
)
fi
makedepends=(cmake qt5-tools)
source=("$pkgname-$pkgver.tar.xz::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"
"$pkgname-$pkgver.tar.xz.sig::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz.sig")
b2sums=('4c536ec062295655c04a360ba3c94ff97078aa03b96e5bb29e246f6ad13cce16ba77bcf5e7232de4df669706bc612f6b157e3050f0d8b9eb4b1f47e4308af0d0'
'SKIP')
# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)
build() {
# lto breaks compiling
# PIE cause the tests to fail
export CFLAGS="$CFLAGS -O3 -fstack-protector-all"
export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all"
cmake -S $pkgname-$pkgver -B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DWITH_XC_AUTOTYPE=ON \
-DWITH_XC_NETWORKING=${_NETBUILD} \
-DWITH_XC_BROWSER=${_NETBUILD} \
-DWITH_XC_YUBIKEY=OFF \
-DWITH_XC_SSHAGENT=${_NETBUILD} \
-DWITH_XC_KEESHARE=${_NETBUILD} \
-DWITH_XC_UPDATECHECK=OFF \
-DWITH_XC_FDOSECRETS=${_NETBUILD}
cmake --build build
}
check() {
cmake --build build --target test
}
package() {
cmake --build build --target install -- DESTDIR="$pkgdir"
}
|