PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Maintainer (Arch): Bruno Pagani <archange@archlinux.org>

# # I maintain this because:
# Arch version uses yubikey libs
# Arch version enables networking support
# Arch version does not use ~/.config
# Arch version lacks additional optimization and hardening flags

_NETBUILD=OFF

pkgname=keepassxc
pkgver=2.6.4
pkgrel=1
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64)
url="https://keepassxc.org/"
license=(GPL)
depends=(argon2 hicolor-icon-theme libgcrypt libsodium libxtst qrencode
         qt5-svg qt5-x11extras quazip
         )
makedepends=(asciidoctor cmake qt5-tools)
optdepends=('xclip: keepassxc-cli clipboard support under X server'
            'wl-clipboard: keepassxc-cli clipboard support under Wayland')
source=("$pkgname-$pkgver.tar.xz::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"
        "$pkgname-$pkgver.tar.xz.sig::https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz.sig"
        keepassxc-quazip1.patch)
b2sums=('ca02e59c7355f7f7e14bb4fa318fab66d354e84d1025847b413b7e838dc5a42024b963dea1e3ba2060c51da7daed2ee5b220e5dab72b5813d39c04b49c6ba9ba'
        'SKIP'
        'ab5e4bd02df5bc3a9a2016ab9042a1611aedbeef9ab1c0787e0079a88fc19c1939acb20f11edec894362737c27a9cfd4339a783a2416dd586c83595e22ff4a89')
# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
              71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
              AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
              C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)

prepare() {
  patch -d $pkgname-$pkgver -p1 -i ../keepassxc-quazip1.patch # Fix build with quazip 1
  sed 's|Exec=keepassxc %f|Exec=keepassxc --localconfig ~/.config/keepassxc/keepassxclocal.ini %f|' $srcdir/$pkgname-$pkgver/share/linux/org.keepassxc.KeePassXC.desktop
}

build() {

  # lto breaks compiling
  # PIE causes the tests to fail
  export CFLAGS="$CFLAGS -O3 -fstack-protector-all"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all"

  cmake -S $pkgname-$pkgver -B build \
        -DCMAKE_BUILD_TYPE=Release \
        -DCMAKE_INSTALL_PREFIX=/usr \
        -DCMAKE_INSTALL_LIBDIR=lib \
    -DWITH_XC_AUTOTYPE=ON \
    -DWITH_XC_NETWORKING=OFF \
    -DWITH_XC_BROWSER=${_NETBUILD} \
    -DWITH_XC_YUBIKEY=OFF \
    -DWITH_XC_SSHAGENT=OFF \
    -DWITH_XC_KEESHARE=OFF \
    -DWITH_XC_FDOSECRETS=OFF \
    -DWITH_XC_UPDATECHECK=OFF
    cmake --build build
}

check() {
    cmake --build build --target test
}

package() {
    cmake --build build --target install -- DESTDIR="$pkgdir"
}