blob: 3d11a301a84b83b1d43438eeaf8504862eb3ea53 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# $Id$
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
pkgname=keepassxc
pkgver=2.2.0
pkgrel=2.arcfour1
pkgdesc="Cross-platform community-driven port of Keepass password manager"
arch=(x86_64 i686)
url="https://keepassxc.org/"
license=(GPL)
depends=(hicolor-icon-theme libxtst qt5-x11extras)
makedepends=(cmake qt5-tools)
source=("https://github.com/keepassxreboot/$pkgname/releases/download/$pkgver/$pkgname-$pkgver-src.tar.xz"{,.sig})
sha512sums=('d27abf4edc9efffeaeb6c43a85551fed6f68f888aef42a59ff8cc51e5d4a5029402587b022c2b089182e2b11834aecf84bf1f3d4bb6804705954c84f135e0ed2'
'SKIP')
validpgpkeys=('BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2') # KeePassXC Release <release@keepassxc.org>
prepare() {
mkdir -p build
}
build() {
cd build
cmake ../$pkgname-$pkgver \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DCMAKE_INSTALL_LIBDIR=lib \
-DWITH_XC_AUTOTYPE=ON \
-DWITH_XC_HTTP=OFF \
-DWITH_XC_YUBIKEY=OFF
make
}
check() {
cd build
# Fails on i686 - https://github.com/keepassxreboot/keepassxc/issues/327
if [ $CARCH == x86_64 ]; then
make test
fi
}
package() {
cd build
make DESTDIR="$pkgdir" install
}
|