PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Fabio 'Lolix' Loli <fabio.loli@disroot.org> -> https://github.com/FabioLolix
# Contributor (AUR): C. Dominik Bódi <dominikdotbodiatgmxdotde>
# Contributor (AUR): Joe Davison <joe@warhaggis.com>

# # I maintain this because:
# AUR version uses http
# AUR version uses unofficial repo
# AUR version needlessly purges old build folder
# AUR version uses qt-webengine
# AUR version lacks additional optimization and hardening flags

pkgname=lgogdownloader
pkgver=3.12
pkgrel=1.2
pkgdesc="Open source downloader for GOG.com games, uses the GOG.com API"
url="https://github.com/Sude-/lgogdownloader"
arch=(x86_64 i686 pentium4)
license=('custom:WTFPL')
options=(lto)
depends=('boost-libs' 'curl' 'htmlcxx'  'jsoncpp' 'rhash' 'tinyxml2')
makedepends=('cmake' 'boost' 'help2man')
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/Sude-/lgogdownloader/archive/v${pkgver}.tar.gz)
b2sums=('46dded2fe584080470166c42a639bc96432e574bc559dd32ec69cf692564eded6d3473374b5c06cff1552cf905c13514bed5ab2394de95571c4c07b5c98ffcad')

prepare() {
    mkdir $srcdir/${pkgname}-${pkgver}/build
}

build() {

  export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

    cd $srcdir/${pkgname}-${pkgver}/build
    cmake .. \
            -DCMAKE_INSTALL_PREFIX=/usr \
            -DCMAKE_BUILD_TYPE=Release \
            -DUSE_QT_GUI=OFF
    make

}

package() {
    cd $srcdir/${pkgname}-${pkgver}/build
    
    make DESTDIR=${pkgdir} install
    install -Dm644 $srcdir/${pkgname}-${pkgver}/COPYING ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
}