1 files changed, 65 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..49982ea
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,65 @@
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (Parabola): David P. <megver83@parabola.nu>
+# Contributor (Parabola): André Silva <emulatorman@hyperbola.info>
+# Contributor (Parabola): Márcio Silva <coadde@hyperbola.info>
+# Contributor (Parabola): Luke Shumaker <lukeshu@sbcglobal.net>
+
+# # I maintain this because:
+# Parabola version conflict with non-libre packages
+
+pkgname=linux-libre-firmware
+pkgver=1.3.1
+pkgrel=1
+epoch=1
+pkgdesc='Firmware files for Linux-libre'
+arch=(any)
+url='https://jxself.org/firmware'
+license=(GPL3)
+makedepends=(arm-linux-gnueabi-gcc arm-none-eabi-gcc cmake sh-elf-gcc sh-elf-newlib xtensa-elf-gcc)
+provides=(linux-firmware)
+conflicts=(linux-firmware
+           linux-firmware-git
+           kernel26-firmware
+           ar9170-fw
+           iwlwifi-1000-ucode
+           iwlwifi-3945-ucode
+           iwlwifi-4965-ucode
+           iwlwifi-5000-ucode
+           iwlwifi-5150-ucode
+           iwlwifi-6000-ucode
+           rt2870usb-fw
+           rt2x00-rt61-fw
+           rt2x00-rt71w-fw
+           amd-ucode
+           openfwwf
+           ath9k-htc-firmware)
+options=(!buildflags !makeflags)
+source=("$url/$pkgname-$pkgver.tar.lz"{,.asc}
+	0001-Add-offline-files-and-a-toolchain-option-in-Makefile.patch)
+sha512sums=('d827ec7024b4900dcdf6af8cdd4e72b02596d0ade5c2262460cd573785300498e6aa655b9a59cd22e38a6a787826a564ae33acfac52e68df1d082445e66f18df'
+            'SKIP'
+            '1aa4b3a463c0d24f295df2ea13e30d3b11a1af7abef3e03558036b07143b3262178a3b7ab6cc0cc7c255044f833e7df9a3cb18b98978e55737852fe0185dc22e')
+validpgpkeys=('F611A908FFA165C699584ED49D0DB31B545A3198') # Jason Self
+
+prepare() {
+  cd $srcdir/$pkgname-$pkgver/src
+
+  patch -p1 -i $srcdir/0001-Add-offline-files-and-a-toolchain-option-in-Makefile.patch
+
+  # Build carl9170 with the default config
+  sed '71s/autogen.sh/autogen.sh --alldefconfig/' -i Makefile
+}  
+
+build() {
+  cd $srcdir/$pkgname-$pkgver
+  make toolchains= -C src
+}
+
+package() {
+  cd $srcdir/$pkgname-$pkgver
+
+  install -dm755 $pkgdir/usr/lib/firmware
+  make -C src prefix=$pkgdir/usr/lib/firmware install
+
+  install -Dm644 src/WHENCE $pkgdir/usr/share/licenses/$pkgname/WHENCE
+}