PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Fabio 'Lolix' Loli <fabio.loli@disroot.org>
# Contributor (AUR): txtsd <aur.archlinux@ihavea.quest>
# Contributor (AUR): Marcel Korpel <marcel[dot]korpel[at]gmail>
# Contributor AUR): Olaf Bauer <hydro@freenet.de>

# # I maintain this because:
# AUR version uses http
# AUR version uses CFLAGS instead of CXXFLAGS

pkgname=makemkv
pkgver=1.17.8
pkgrel=1
pkgdesc="DVD and Blu-ray to MKV converter"
arch=('x86_64' 'i686' 'aarch64')
url="https://www.makemkv.com"
license=('LicenseRef-GuinpinSoft-inc-EULA' 'LGPL-2.1-or-later')
depends=('qt5-base' 'ffmpeg' 'libavcodec.so')
optdepends=('java-runtime: BD-Java support')
install=makemkv.install
source=(https://www.makemkv.com/download/${pkgname}-bin-${pkgver}.tar.gz
        https://www.makemkv.com/download/${pkgname}-oss-${pkgver}.tar.gz
        makemkv.1
        makemkvcon.1)
sha256sums=('8e0f547430d9afeed976c789b5becdfb2ecfae1caade12e8e3e119a734717041'
            '92752bce3fc9f97939375b60d2af622174fe86a4ad9248cbdd8736629e6dbc8a'
            '5573b2e4bade10d8cd258a7c235eb46f66ef8c8c97e5d5eb090c38fa0f94389b'
            'f12c0facf2f0071a9f728b138986f0a4c2b4ff6ace2dfb2e96364e215e9fda6f')
b2sums=('0ddbcd50a44a98c118420485c7c8e48a1c03290ac840b22ab8119d5cd6db0743e746ca9cbdd7fd714f49a2a37420645c820477c5c7d7b189763b5a46de342e9d'
        '76ffcf0a67c2ee6b05820006ff7926accef7939374b328d709dbbf6c746f010e273f89748a2a3386679b83f2af0b4f3e41f31e8acaf29cdbaeffccaf25b57500'
        '92bac30ca1ca062bb235389ac9e558649c7efc31b7690a4540cae6f9f032843ce4ed74eb091bcfba1e24ad0fbc904963c7aed2d6761883800ef319a3ed074cd0'
        'a318361982271bee3db2fa6f3e2b51afd7fe35f3dcb821c24bc21f8189be74cf9093559dbf9689eedd458226b30ddf59333af10ef509dc850331639b9035be39')

build() {
  cd "${srcdir}/${pkgname}-oss-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-oss-${pkgver}"
  make DESTDIR="${pkgdir}" install

  cd "${srcdir}/${pkgname}-bin-${pkgver}"
  install -d tmp
  echo accepted > tmp/eula_accepted
  make DESTDIR="${pkgdir}" install

  install -Dm 644 src/eula_en_linux.txt "${pkgdir}/usr/share/licenses/${pkgname}/eula_en_linux.txt"

  cd "${srcdir}/"
  install -d "${pkgdir}/usr/share/man/man1/"
  install -m 644 -t "${pkgdir}/usr/share/man/man1/" makemkv.1 makemkvcon.1
}