PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Fabio 'Lolix' Loli <fabio.loli@disroot.org>
# Contributor (AUR): txtsd <aur.archlinux@ihavea.quest>
# Contributor (AUR): Marcel Korpel <marcel[dot]korpel[at]gmail>
# Contributor AUR): Olaf Bauer <hydro@freenet.de>

# # I maintain this because:
# AUR version uses http
# AUR version uses CFLAGS instead of CXXFLAGS

pkgname=makemkv
pkgver=1.17.7
pkgrel=4
pkgdesc="DVD and Blu-ray to MKV converter"
arch=('x86_64' 'i686' 'aarch64')
url="https://www.makemkv.com"
license=('LicenseRef-GuinpinSoft-inc-EULA' 'LGPL-2.1-or-later')
depends=('qt5-base' 'ffmpeg' 'libavcodec.so')
optdepends=('java-runtime: BD-Java support')
install=makemkv.install
source=(https://www.makemkv.com/download/${pkgname}-bin-${pkgver}.tar.gz
        https://www.makemkv.com/download/${pkgname}-oss-${pkgver}.tar.gz
        makemkv.1
        makemkvcon.1)
sha256sums=('8c5bc831bc952b1f873cc8450c64e392db0b2479b626d180f0ffc965668951d0'
            '762e552d46f9ec75a7c62dcb7d97c0fd9e6a15120d0ef6f5a080cee291d3a0ef'
            '5573b2e4bade10d8cd258a7c235eb46f66ef8c8c97e5d5eb090c38fa0f94389b'
            'f12c0facf2f0071a9f728b138986f0a4c2b4ff6ace2dfb2e96364e215e9fda6f')
b2sums=('adc54191fd445832b9c4805400746e42d1b3261d076299b5e34beb1f13d80bf7bcbd113699f3d28fce5e21bb8f810a40927924b3d9c7250467d1979b1bf4f72b'
        '18652db1d72ea7287e7e38706afc589e6fe8fb1fbf9d4e24770b9a2bfe670a464b2c21b7c543b23d3c6234f40048358d944b123897c4f569beb31faac8ef3eb7'
        '92bac30ca1ca062bb235389ac9e558649c7efc31b7690a4540cae6f9f032843ce4ed74eb091bcfba1e24ad0fbc904963c7aed2d6761883800ef319a3ed074cd0'
        'a318361982271bee3db2fa6f3e2b51afd7fe35f3dcb821c24bc21f8189be74cf9093559dbf9689eedd458226b30ddf59333af10ef509dc850331639b9035be39')

build() {
  cd "${srcdir}/${pkgname}-oss-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-oss-${pkgver}"
  make DESTDIR="${pkgdir}" install

  cd "${srcdir}/${pkgname}-bin-${pkgver}"
  install -d tmp
  echo accepted > tmp/eula_accepted
  make DESTDIR="${pkgdir}" install

  install -Dm 644 src/eula_en_linux.txt "${pkgdir}/usr/share/licenses/${pkgname}/eula_en_linux.txt"

  cd "${srcdir}/"
  install -d "${pkgdir}/usr/share/man/man1/"
  install -m 644 -t "${pkgdir}/usr/share/man/man1/" makemkv.1 makemkvcon.1
}