blob: 65c466db452cb0bf2988653c81ae82620b9a8979 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
pkgname=mupen64plus-qt
pkgver=1.15
pkgrel=2
pkgdesc="A customizable launcher for Mupen64Plus"
arch=('i686' 'x86_64')
url="https://github.com/dh4/mupen64plus-qt"
license=('BSD')
depends=('quazip' 'mupen64plus' 'hicolor-icon-theme')
install=mupen64plus-qt.install
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/dh4/${pkgname}/archive/${pkgver}.tar.gz"
"quazip-fix.patch")
b2sums=('9db7c5c7fefa99466933e4526338487b138eb970595d0ac92aedb1649e9786785b2472b7716cd24080e99cddda9d434207d2387515a62f6b2c111076bdcb10ed'
'862c4291d7131f7be22cbb6c2ec70fcacf8638850ec4d6cb397f84901a63ea0e32dcef5741fe11304f6b63c4a66c11ddf288660d13f65966840a3e3e7b08dd8e')
prepare() {
cd "$srcdir/$pkgname-$pkgver"
patch -Np1 -i "$srcdir"/quazip-fix.patch
}
build() {
cd "$srcdir/$pkgname-$pkgver"
export CFLAGS="$CFLAGS -O3 -flto=auto -fPIE"
export CXXFLAGS="$CXXFLAGS -O3 -flto=auto -fPIE"
export LDFLAGS="$LDFLAGS,-pie"
qmake-qt5
make
}
package() {
cd "$srcdir/$pkgname-$pkgver"
install -Dm755 "mupen64plus-qt" "$pkgdir/usr/bin/mupen64plus-qt"
install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
install -Dm644 "resources/mupen64plus-qt.desktop" "$pkgdir/usr/share/applications/mupen64plus-qt.desktop"
install -Dm644 "resources/images/mupen64plus.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/mupen64plus-qt.png"
}
|
