PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>

# # I maintain this because:
# Arch version lacks additional optimization and hardening flags

pkgname=mupen64plus-qt
pkgver=1.14
pkgrel=1
pkgdesc="A customizable launcher for Mupen64Plsu"
arch=('i686' 'x86_64')
url="https://github.com/dh4/mupen64plus-qt"
license=('BSD')
depends=('quazip' 'mupen64plus' 'hicolor-icon-theme')
install=mupen64plus-qt.install
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/dh4/${pkgname}/archive/${pkgver}.tar.gz")
b2sums=('f81681861de61db9e68eb80941e97644a2e903b221c470e981c9e7f39e3cc720f59e57a08a7d5346b99ae963d6639c275c98f6519df9a203b0aaf567e9169451')

build() {
  cd "$srcdir/$pkgname-$pkgver"

  export CFLAGS="$CFLAGS -O3 -flto=4 -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -flto=4 -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"

  qmake-qt5
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -Dm755 "mupen64plus-qt" "$pkgdir/usr/bin/mupen64plus-qt"
  install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 "resources/mupen64plus-qt.desktop" "$pkgdir/usr/share/applications/mupen64plus-qt.desktop"
  install -Dm644 "resources/images/mupen64plus.png" "$pkgdir/usr/share/icons/hicolor/128x128/apps/mupen64plus-qt.png"
}