PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): Sandy Carter <bwrsandman@gmail.com>

# # I maintain this because:
# Arch version lacks additional optimization and hardening flags

pkgname=openmw
pkgver=0.46.0
pkgrel=4
pkgdesc="Open-source engine reimplementation for the role-playing game Morrowind"
arch=('x86_64')
url="http://www.openmw.org"
license=('GPL3' 'MIT' 'custom')
depends=('openal' 'openscenegraph' 'mygui' 'bullet' 'qt5-base' 'ffmpeg' 'sdl2' 'unshield' 'libxt' 'libvdpau')
makedepends=('cmake' 'boost' 'doxygen' 'ninja')
source=("https://github.com/OpenMW/openmw/archive/openmw-${pkgver}.tar.gz"
        "openmw-0.46.0-missing-include.patch")
b2sums=('8ad94a7fffe5a0739c56c778efe2ec17ef66c312a7fe5caf015cf3cad2bc17d2abe8cdc3f4134049a32fe55c4f4b3f72678d2d0ce1037fd02f6ac753b9d89b2c'
        'fa80b94d9ce91e1b05b96c02e80f32f1e9066ba6f8ada4a1e5150cf3a278d3a233eda42269b3027c56aaa7be98dd33cbcc3932d1e0930a51bd6b5744a73d6b6e')

prepare() {
  cd ${pkgname}-${pkgname}-${pkgver}
  patch -Np1 -i ${srcdir}/openmw-0.46.0-missing-include.patch
}

build() {
  cd ${pkgname}-${pkgname}-${pkgver}
  # gcc 10.2 + qt 5.15 + pie = segfault
  export CFLAGS="$CFLAGS -O3 -flto=4"
  export CXXFLAGS="$CXXFLAGS -O3 -flto=4"
  cmake . \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DDESIRED_QT_VERSION=5 \
    -GNinja \
    -Bbuild
  ninja -C build "$MAKEFLAGS"
}

package() {
  cd ${pkgname}-${pkgname}-${pkgver}
  DESTDIR="$pkgdir" ninja -C build install
}