Initial commit

2 files changed, 90 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..32faf18
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,74 @@
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (AUR): Graham Edgecombe <graham@grahamedgecombe.com>
+
+# # I maintain this because:
+# AUR version lacks additional optimization and hardening flags
+# AUR version builds with discord
+
+pkgname=openrct2
+pkgver=0.2.4
+_titlepkgver=0.1.2c
+_objectpkgver=1.0.12
+_replayspkgver=0.0.4
+pkgrel=1
+pkgdesc='Open source re-implementation of Roller Coaster Tycoon 2 (Original copy required)'
+arch=('i686' 'x86_64' 'armv7h' 'aarch64')
+url='https://openrct2.io'
+license=('GPL3')
+depends=('hicolor-icon-theme' 'sdl2' 'jansson' 'speexdsp' 'fontconfig'
+         'libpng' 'libzip' 'icu')
+makedepends=('cmake')
+optdepends=('zenity: System dialog box support (GNOME/GTK)'
+            'kdialog: System dialog box support (KDE)'
+            'alsa-lib: ALSA audio driver'
+            'libpulse: PulseAudio audio driver')
+install=openrct2.install
+source=($pkgname-$pkgver.tar.gz::https://github.com/OpenRCT2/OpenRCT2/archive/v$pkgver.tar.gz
+        $pkgname-title-sequences-$_titlepkgver.zip::https://github.com/OpenRCT2/title-sequences/releases/download/v$_titlepkgver/title-sequences.zip
+        $pkgname-objects-$_objectpkgver.zip::https://github.com/OpenRCT2/objects/releases/download/v$_objectpkgver/objects.zip
+        $pkgname-replays-$_replayspkgver.zip::https://github.com/OpenRCT2/replays/releases/download/v$_replayspkgver/replays.zip
+        )
+b2sums=('7860746d1705804682756097ff37d4584d0ebb20c450c08b88134795e9f3c375dfb888a67302f530cd55700eaa5cd13149c365c30a5d267d382b39225f06d210'
+        'f91168bea0a4f88a801c95ea45759e0d1c887a89c18dbbded5887d2914db7119dd65c231aa422e4f8a964a81d832eae05bffaa8b7908fac39a63792d082b53a0'
+        'd344dde3dc376004b9e303a489c058a574c2f8babcce8c9998ef12f2b91e3fe7d3e22e1afc81aadd39637f3f91a5d36c4267aed06980686fd909cc515f4c8fde'
+        'efe4f72b16285d8e6508313f16b892b02f1b124cf9b4d146731280f5090d071d3351834e6d4ab51122804fbbcb49044be4e681182141aac93795c3b1953b6590')
+
+prepare() {
+  cd "$srcdir/OpenRCT2-$pkgver"
+  mkdir data/title
+  cp -r $srcdir/*.parkseq data/title
+  mkdir data/object
+  cp -r $srcdir/official data/object
+  cp -r $srcdir/rct1 data/object
+  cp -r $srcdir/rct2 data/object
+  cp -r $srcdir/rct2tt data/object
+  cp -r $srcdir/rct2ww data/object
+  mkdir -p testdata/replays
+  cp -r $srcdir/*.sv6r testdata/replays
+}
+
+build() {
+  cd "$srcdir/OpenRCT2-$pkgver"
+
+  mkdir -p build
+  cd build
+  cmake -DCMAKE_BUILD_TYPE=RelWithDebInfo    \
+        -DCMAKE_INSTALL_PREFIX=/usr          \
+        -DCMAKE_INSTALL_LIBDIR=/usr/lib      \
+        -DDOWNLOAD_TITLE_SEQUENCES=OFF \
+        -DDOWNLOAD_OBJECTS=OFF         \
+        -DDOWNLOAD_REPLAYS=OFF         \
+        -DDISABLE_HTTP_TWITCH=ON       \
+        -DDISABLE_NETWORK=ON           \
+        ..
+  make all g2
+}
+
+package() {
+  cd "$srcdir/OpenRCT2-$pkgver/build"
+
+  make DESTDIR="$pkgdir" install
+
+  rm -rf "$pkgdir/usr/lib"
+  rm -rf "$pkgdir/usr/include"
+}
diff --git a/openrct2.install b/openrct2.install
new file mode 100644
index 0000000..6dfeac9
--- /dev/null
+++ b/openrct2.install
@@ -0,0 +1,16 @@
+post_install() {
+  cat <<EOF
+For OpenRCT2 to run you must install the assets from a retail copy of
+RollerCoaster Tycoon 2. See the following page for more information on
+installing a retail copy of the game on Linux:
+
+  https://github.com/OpenRCT2/OpenRCT2/wiki/Installation-on-Linux,-macOS
+
+If kdialog or zenity is available, OpenRCT2 will prompt you for the location of
+the retail install the first time you start it.
+
+Alternatively, manually set the location of retail install:
+
+  openrct2 set-rct2 /path/to/RCT2/
+EOF
+}