blob: a6d8369a657edb84d872c942b5804e90c6d18e0a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Jelle van der Waa <jelle@archlinux.org>
# Contributor (AUR): Graham Edgecombe <graham@grahamedgecombe.com>
# # I maintain this because:
# Arch version lacks additional optimization and hardening flags
# Arch version builds with discord, benchmark, update checks, online tests
# Arch version cannot be built offline
pkgname=openrct2
pkgver=0.4.4
_titlepkgver=0.4.0
_objectpkgver=1.3.8
_opensfxpkgver=1.0.2
_openmsxpkgver=1.1.0
_replayspkgver=0.0.77
pkgrel=1
pkgdesc='Open source re-implementation of Roller Coaster Tycoon 2 (requires full copy of the game)'
arch=('x86_64' 'i686' 'armv7h' 'aarch64')
url='https://openrct2.io'
license=('GPL3')
depends=('hicolor-icon-theme' 'sdl2' 'speexdsp'
'fontconfig' 'libpng' 'libzip' 'icu'
'libogg' 'libvorbis' 'flac')
makedepends=('cmake' 'nlohmann-json')
optdepends=('zenity: System dialog box support (GNOME/GTK)'
'kdialog: System dialog box support (KDE)'
'alsa-lib: ALSA audio driver'
'libpulse: PulseAudio audio driver')
options=('lto')
install=openrct2.install
source=($pkgname-$pkgver.tar.gz::https://github.com/OpenRCT2/OpenRCT2/archive/v${pkgver}.tar.gz
$pkgname-title-sequences-$_titlepkgver.zip::https://github.com/OpenRCT2/title-sequences/releases/download/v${_titlepkgver}/title-sequences.zip
$pkgname-objects-$_objectpkgver.zip::https://github.com/OpenRCT2/objects/releases/download/v${_objectpkgver}/objects.zip
$pkgname-opensfx-$_opensfxpkgver.zip::https://github.com/OpenRCT2/OpenSoundEffects/releases/download/v${_opensfxpkgver}/opensound.zip
$pkgname-openmsx-$_openmsxpkgver.zip::https://github.com/OpenRCT2/OpenMusic/releases/download/v${_openmsxpkgver}/openmusic.zip
$pkgname-replays-$_replayspkgver.zip::https://github.com/OpenRCT2/replays/releases/download/v${_replayspkgver}/replays.zip
)
sha256sums=('18970bfffe49c77fa81ea6c295119b173a613c7310d7762963458e3e77c24913'
'6e7c7b554717072bfc7acb96fd0101dc8e7f0ea0ea316367a05c2e92950c9029'
'84a95590d13a753b1d239f7f06c8d121e36fd28694b21f33646518e2012904ae'
'ab93e7d88190eec40b66cff84cacdb9fadc6b993fa769d4fd22ce9de98d5d22c'
'e53e1b6c25deb81a2e1c19130d2935daa7a6741a45b46dbb58fd713135a98728'
'7e6c889368a3b266a2301dfcde9e2a52f9e84041dd6a9252d6201c555ea2cdb2')
b2sums=('f0770b7db82b9df5325e8740b5aa88889ac5354b07b271c824f9521ba02d0bc3eec395f216305d4737c8ad36a3096281d1a7ecb019a6514399b7d12dec0dd526'
'51f07af30c3702754d806829fe612891a883adc70b8e89f64094b28c94879e5c98feca69f3c1f389ceeb33a99175b41afa794a4f2d121280dcce97c428d2ea99'
'84f104666671fe7b677390e0475fdd0b7a417ab52ece7e7b6ea8dcf5ec21cda5ffc95cf5fb989d3e8d2a353132580eacafbee3a5655c79e4528328fabc607af0'
'3f6cd64a13dc2562598a2aacc15ac26ac266f56c2d04a304e2b0610b8205a2d18b524687b9b840dbe349cb4b3384fbd57ed207c5ccd194cc2e1d4dd351795a79'
'94cdea7ef6813e5238642f6eb57d32d306a0ff9ffd0884a7b90c749ce6be6dffd1e97da55ccbed6fbfb86a9b2143cb845b873878c6b7d55f44d9da6dc66e5bdd'
'38bce55f91f49a485d158a94b4ce553ffa606f652cd766b33acf299b86304ea0507b50441b2a9b1fb219b90a0dc2426eff5988c2b128a97e399b00c3392f10e0')
prepare() {
cd "$srcdir/OpenRCT2-$pkgver"
# Add titles data
mkdir data/sequence
cp -r --reflink $srcdir/*.parkseq data/sequence
# Add objects data
mkdir data/object
cp -r --reflink $srcdir/official data/object
cp -r --reflink $srcdir/rct1 data/object
cp -r --reflink $srcdir/rct2 data/object
cp -r --reflink $srcdir/rct2tt data/object
cp -r --reflink $srcdir/rct2ww data/object
# Add opensfx data
mkdir data/assetpack
mkdir data/object/official/audio
cp -r --reflink $srcdir/assetpack/openrct2.sound.parkap data/assetpack/
cp -r --reflink $srcdir/object/official/audio/openrct2.audio.additional.parkobj data/object/official/audio/
# Add openmsx data
mkdir data/object/official/music
cp -r --reflink $srcdir/assetpack/openrct2.music.alternative.parkap data/assetpack/
cp -r --reflink $srcdir/object/official/music/*.parkobj data/object/official/music/
# Add replays data
mkdir -p testdata/replays
cp -r --reflink $srcdir/*.parkrep testdata/replays
mkdir -p build
}
build() {
cd "$srcdir/OpenRCT2-$pkgver/build"
# Needed to be able to build while LTO is enabled
# https://github.com/OpenRCT2/OpenRCT2/issues/6200
CXXFLAGS+=" -Wno-error=stringop-overflow -Wno-error=nonnull"
# Required options to workaround GCC 12 issues
# https://github.com/OpenRCT2/OpenRCT2/issues/17371
CXXFLAGS+=" -Wno-error=maybe-uninitialized -Wno-error=restrict -Wno-error=null-dereference"
# Required for -DDISABLE_NETWORK as of 0.3.3
CXXFLAGS+=" -Wno-error=unused-const-variable"
export CFLAGS="$CFLAGS -O3 -fstack-protector-all -fPIE"
export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -fPIE"
export LDFLAGS="$LDFLAGS,-pie"
cmake -DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DSTATIC=OFF \
-DCMAKE_INSTALL_LIBDIR=/usr/lib \
-DDOWNLOAD_TITLE_SEQUENCES=OFF \
-DDOWNLOAD_OBJECTS=OFF \
-DDOWNLOAD_OPENSFX=OFF \
-DDOWNLOAD_OPENMSX=OFF \
-DDOWNLOAD_REPLAYS=OFF \
-DDISABLE_DISCORD_RPC=ON \
-DDISABLE_GOOGLE_BENCHMARK=ON \
-DDISABLE_HTTP=ON \
-DDISABLE_NETWORK=ON \
..
make all g2
}
package() {
cd "$srcdir/OpenRCT2-$pkgver/build"
make DESTDIR="$pkgdir" install
rm "$pkgdir/usr/lib/libopenrct2.a"
rmdir "$pkgdir/usr/lib"
}
|
