Initial commit

1 files changed, 74 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..8dde6e2
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,74 @@
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (AUR):  WorMzy Tykashi <wormzy.tykashi@gmail.com>
+# Contributor (AUR): artiom <a.mv at gmx dot fr>
+# Contributor (AUR): ilikenwf
+# Contributor (AUR): American_Jesus
+
+# # I maintain this because:
+# AUR version uses git
+# AUR version does not use system libs
+
+pkgname=palemoon
+pkgver=28.5.0
+pkgrel=1
+pkgdesc="Open source web browser based on Firefox focusing on efficiency."
+arch=(x86_64 i686)
+license=(MPL GPL LGPL)
+url="https://www.palemoon.org/"
+depends=(gtk2 desktop-file-utils libxt startup-notification mime-types dbus-glib
+         libpulse alsa-lib
+         libffi bzip2 cairo icu libjpeg-turbo libevent libvpx nspr nss pixman libpng sqlite zlib)
+makedepends=(unzip zip python2 yasm gconf
+             jack
+             autoconf2.13)
+optdepends=('ffmpeg: various video and audio support'
+            'alsa-utils: ALSA support'
+            'jack: Jack support'
+            'pulseaudio: PulseAudio support'
+            'hunspell-en_CA: Spell checking, Canadian English')
+source=(palemoon-$pkgver.tar.gz::https://github.com/MoonchildProductions/UXP/archive/PM${pkgver}_Release.tar.gz
+        mozconfig.in
+        system-libs.patch)
+sha256sums=('bf7bc91dce0b992d3ce8ed8d6b332bbb9b3d1191847133d3401c0612827f1930'
+            '12036d3ee0d2586c39f26fd42e3ec692a318789844b4a8fc0648df5725b1324b'
+            'ddd6e39161b789c3dab7e963d5f837b5a72155c59f88abc66dce5fe9d5d0a2e9')
+
+prepare() {
+  sed 's#%SRCDIR%#'"$srcdir"'#g' mozconfig.in > mozconfig
+  sed -i 's#xlocale#locale#' UXP-PM${pkgver}_Release/intl/icu/source/i18n/digitlst.cpp
+}
+
+build() {
+  cd UXP-PM${pkgver}_Release
+
+  # I'll use system libs if I darn well choose, thank you very much.
+  patch -Np1 -i ../system-libs.patch
+  rm build/directive4.py
+
+  export MOZBUILD_STATE_PATH="$srcdir/mozbuild"
+  export MOZCONFIG="$srcdir/mozconfig"
+  export CPPFLAGS="$CPPFLAGS -O2"
+  python2 mach build
+}
+
+package() {
+  cd pmbuild
+  make package
+  cd dist
+  install -d "$pkgdir"/usr/{bin,lib}
+  cp -r palemoon/ "$pkgdir/usr/lib/$pkgname"
+  ln -s "../lib/$pkgname/palemoon" "$pkgdir/usr/bin/palemoon"
+
+  # icons
+  install -Dm644 palemoon/browser/chrome/icons/default/default16.png \
+    "$pkgdir/usr/share/icons/hicolor/16x16/apps/$pkgname.png"
+  install -Dm644 palemoon/browser/chrome/icons/default/default32.png \
+    "$pkgdir/usr/share/icons/hicolor/32x32/apps/$pkgname.png"
+  install -Dm644 palemoon/browser/chrome/icons/default/default48.png \
+    "$pkgdir/usr/share/icons/hicolor/48x48/apps/$pkgname.png"
+  install -Dm644 palemoon/browser/icons/mozicon128.png \
+    "$pkgdir/usr/share/icons/hicolor/128x128/apps/$pkgname.png"
+
+  # install desktop file
+  install -Dm644 "$srcdir/UXP-PM${pkgver}_Release/application/palemoon/branding/official/palemoon.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
+}