blob: 8c0f0805818e6a6943564ef831ddcccfcf61a5ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): WorMzy Tykashi <wormzy.tykashi@gmail.com>
# Contributor (AUR): artiom <a.mv at gmx dot fr>
# Contributor (AUR): ilikenwf
# Contributor (AUR): American_Jesus
# # I maintain this because:
# AUR version uses git
# AUR version does not use system libs
pkgname=palemoon
_pmaltname=pale-moon
_uxpaltname=uxp
pkgver=28.15.0
_uxpver=20201024
pkgrel=1
pkgdesc="Open source web browser based on Firefox focusing on efficiency."
arch=(x86_64 i686)
license=(MPL GPL LGPL)
url="https://www.palemoon.org/"
depends=(gtk2 desktop-file-utils libxt startup-notification mime-types dbus-glib
libpulse alsa-lib
bzip2 libffi hunspell libjpeg-turbo pixman zlib)
makedepends=(unzip zip python2 yasm
jack
autoconf2.13)
optdepends=('ffmpeg: various video and audio support'
'alsa-utils: ALSA support'
'jack: Jack support'
'pulseaudio: PulseAudio support'
'palemoon-preferences: Custom vendor.js with security by default'
'palemoon-preferences-basic: Custom vendor.js with less breaking changes')
source=($pkgname-$pkgver.tar.gz::https://repo.palemoon.org/MoonchildProductions/Pale-Moon/archive/${pkgver}_Release.tar.gz
$_uxpaltname-$_uxpver.tar.gz::https://repo.palemoon.org/MoonchildProductions/UXP/archive/RELBASE_${_uxpver}.tar.gz
mozconfig.in
system-libs.patch)
b2sums=('aff58b9d12e7f9a60b20a5e87f8a947c12489528c0f44df953800a3aad2116ac8708bc73b538f3f7ce3dd12810854d26fa4db99652f38e1ba5605482c9153f55'
'bb9c1ebd334235ed5982c15cbb490c918798c36b7bf6b39a03db9b74361ac33c7385da0bf19d36f146a93837c1ffe654af2c07a191c45d837820ad5bbbe6b85c'
'402dc4a3cc7e24227fbe8f4744112323c445f214c0d0f58126e12f8f6b37545a8e15f95526ef6b6ff008ae94cd4e072309b22871bcbedf6921e4ad0937435576'
'47cc9da19cb7003ea896e8d1f3f77197548cf917c943ec1bd8526daaf6212d2c2c90bc417df156ee571c9ca052749a6a3a13f8acc150f1983a8bf0f8f1ebe2de')
validpgpkeys=('3059E09144F56804F0FBF4E126B40624BDBFD9F3')
prepare() {
sed 's#%SRCDIR%#'"${srcdir}"'#g' mozconfig.in > mozconfig
cd ${_pmaltname}
rm -rf platform
mv ../${_uxpaltname} platform
# I'll use system libs if I darn well choose, thank you very much.
patch -Np1 -i ../system-libs.patch
rm platform/build/directive4.py
}
build() {
cd ${_pmaltname}
export MOZBUILD_STATE_PATH="${srcdir}/mozbuild"
export MOZCONFIG="${srcdir}/mozconfig"
export CFLAGS="$CFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
export CXXFLAGS="$CXXFLAGS -O3 -fstack-protector-all -flto=4 -fPIC"
./mach build
}
package() {
cd pmbuild
make package
cd dist
install -d "${pkgdir}"/usr/{bin,lib}
cp -r palemoon/ "${pkgdir}/usr/lib/${pkgname}"
ln -s "/usr/lib/${pkgname}/palemoon" "${pkgdir}/usr/bin/palemoon"
# icons
install -Dm644 ${srcdir}/${_pmaltname}/palemoon/branding/official/default16.png \
"${pkgdir}/usr/share/icons/hicolor/16x16/apps/${pkgname}.png"
install -Dm644 ${srcdir}/${_pmaltname}/palemoon/branding/official/default32.png \
"${pkgdir}/usr/share/icons/hicolor/32x32/apps/${pkgname}.png"
install -Dm644 ${srcdir}/${_pmaltname}/palemoon/branding/official/default48.png \
"${pkgdir}/usr/share/icons/hicolor/48x48/apps/${pkgname}.png"
install -Dm644 ${srcdir}/${_pmaltname}/palemoon/branding/official/mozicon128.png \
"${pkgdir}/usr/share/icons/hicolor/128x128/apps/${pkgname}.png"
# install desktop file
install -Dm644 "${srcdir}/${_pmaltname}/palemoon/branding/official/palemoon.desktop" \
"${pkgdir}/usr/share/applications/${pkgname}.desktop"
}
|
