PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

# # I maintain this because:
# Arch version depends on ModemManager and MM conflicts with NeuG
# Arch version does not explicitly specify /usr/lib

_pkgname=plasma-nm
pkgname=$_pkgname-neug
pkgver=5.18.2
pkgrel=1
pkgdesc='Plasma applet written in QML for managing network connections'
arch=(x86_64)
url='https://www.kde.org/workspaces/plasmadesktop/'
license=(GPL2)
depends=(plasma-workspace networkmanager-qt qca rng-tools-openrc-neug)
makedepends=(extra-cmake-modules openconnect)
optdepends=('openconnect: Cisco AnyConnect VPN plugin')
groups=(plasma)
conflicts=(plasma-nm modemmanager modemmanager-qt)
provides=(plasma-nm)
source=("https://download.kde.org/stable/plasma/$pkgver/$_pkgname-$pkgver.tar.xz"{,.sig})
b2sums=('c08cb25f42d9940f15ba25c66a5b55cef638f3305706a31258e0d107d10061682e67d767ba0100ccce8b91fe104dbe313a1311d807826b29cee0e406a77843d7'
        'SKIP')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

prepare() {
  mkdir -p build
} 

build() {
  cd build
  cmake ../$_pkgname-$pkgver \
    -DCMAKE_INSTALL_LIBDIR=/usr/lib \
    -DBUILD_TESTING=OFF \
    -DDISABLE_MODEMMANAGER_SUPPORT=ON
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}