PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Antonio Rojas <arojas@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>

# # I maintain this because:
# Arch version depends on ModemManager and MM conflicts with NeuG
# Arch version does not explicitly specify /usr/lib

_pkgname=plasma-nm
pkgname=$_pkgname-neug
pkgver=5.19.2
pkgrel=1
pkgdesc='Plasma applet written in QML for managing network connections'
arch=(x86_64)
url='https://www.kde.org/workspaces/plasmadesktop/'
license=(GPL2)
depends=(plasma-workspace networkmanager-qt qca rng-tools-openrc-neug)
makedepends=(extra-cmake-modules openconnect)
optdepends=('openconnect: Cisco AnyConnect VPN plugin')
groups=(plasma)
conflicts=(plasma-nm modemmanager modemmanager-qt)
provides=(plasma-nm)
source=(https://download.kde.org/stable/plasma/$pkgver/$_pkgname-$pkgver.tar.xz{,.sig}
        kdebug-423093.patch::"https://invent.kde.org/plasma/plasma-nm/commit/271332cf.patch")
b2sums=('0c8a2c67aa24ff29cf43db7e8b8839a487f6a00e99a0277d3dcacfaf22bd01b835380950c6e6a97c6ff10f3120d29e061523fa49acacbb1deb0b3f596d7b276b'
        'SKIP'
        '3dcdd2d4b8ec3c7cb9c65c23cd726ff601270ff9b21a7b240146965a9160fce0019b5e436959b97cb54c367b7d8084a5b281f0b50664b72622efa9cd612df843')
validpgpkeys=('2D1D5B0588357787DE9EE225EC94D18F7F05997E'  # Jonathan Riddell <jr@jriddell.org>
              '0AAC775BB6437A8D9AF7A3ACFE0784117FBCE11D'  # Bhushan Shah <bshah@kde.org>
              'D07BD8662C56CB291B316EB2F5675605C74E02CF'  # David Edmundson <davidedmundson@kde.org>
              '1FA881591C26B276D7A5518EEAAF29B42A678C20') # Marco Martin <notmart@gmail.com>

prepare() {
  # Fix plasma-nm asking twice for password
  patch -d $_pkgname-$pkgver -p1 -i ../kdebug-423093.patch
}

build() {
  cmake -B build -S $_pkgname-$pkgver \
    -DBUILD_TESTING=OFF \
    -DDISABLE_MODEMMANAGER_SUPPORT=ON
  cmake --build build
}

package() {
  DESTDIR="$pkgdir" cmake --install build
}