PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

# Maintainer: Jiachen Yang <farseerfc@gmail.com>
# AUR Maintainer: Vlad M. <vlad@archlinux.net>
# Contributor: Håvard Pettersson <mail@haavard.me>
# Contributor: Kevin MacMartin <prurigro at gmail dot com>

pkgname=qtox
_pkgname=qTox
pkgver=1.15.0
pkgrel=2
_gitver='02d6c63acaac0ae95fa8be3a1b9301657e6a4a94'
pkgdesc='Powerful Tox client written in C++/Qt that follows the Tox design guidelines'
arch=('x86_64')
url='https://github.com/qTox/qTox'
license=('GPL3')
depends=('desktop-file-utils'
         'libxss'
         'openal'
         'gtk2'
         'ffmpeg'
         'qrencode'
         'qt5-svg'
         'sqlcipher'
	     'libexif'
         'toxcore')
makedepends=('qt5-tools' 'git' 'check' 'cmake')

source=(
        "qtox-$pkgver.tar.lz::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz"
        "qtox-$pkgver.tar.lz.asc::https://github.com/$_pkgname/$_pkgname/releases/download/v$pkgver/v$pkgver.tar.lz.asc"
        )
sha512sums=('117d903b069369b404d4fe8b80df9520cfa06455ef99a39780875be53d0efad931e209c476b15b27228338cf5dca6cfdd4b782d8025c1299ba64a5c8d69ed054'
            'SKIP')

validpgpkeys=('DA262CC93C0E1E525AD21C8596775D454B8EBF44'  # sudden6 <sudden6@gmx.at>
              'BA7883E22F9D35945BA3376053137C3033F09008'  # Zetok Zalbavar <zetok@openmailbox.org>
	      '31039166FA902CA50D05D6085AF9F2E29107C727'  # - Diadlo
	      'C7A2552D0B250F983827742C133203A3AC399151'  # - initramfs
	      '2880C860D95C909D3DA45C687E086DD661263264'  # - tux3
          '74ADB7A7F8ECC1009916C4E42AA8E0DA1B31FB3C'  # - AnthonyBilinski subkey
          '7EB339FE881747E701B7D472EBE36E66A8429B99'  # - AnthonyBilinski
          'CA9221C5389B7C50AA5F779352A50775BE13DF17'  # - noavarice
          '141C880E8BA25B198D0F850F7C132143C1A3A7D4'  # – tox-user
             )

prepare() {
  sed -e 's|-Werror||' -i CMakeLists.txt
}

check() {
  cd build
  make test
}

build() {
  mkdir -p build
  cd build
  cmake .. -DCMAKE_INSTALL_PREFIX=/usr \
	  -DGIT_VERSION=$_gitver \
        -DGIT_DESCRIBE=v$pkgver \
        -DSMILEYS=DISABLED
  make
}

package() {
  cd build
  make DESTDIR="$pkgdir" install
}