Initial commit

1 files changed, 36 insertions, 0 deletions

diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..7715d99
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,36 @@
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (AUR): ainola
+# Contributor (AUR): fledge (Giorgio Daino)
+
+# # I maintain this because:
+# AUR version doesn't set file extension on source package
+# AUR version doesn't cd to the correct subdirectory
+
+pkgname=residualvm
+pkgver=0.3.1
+pkgrel=3
+pkgdesc="A cross-platform 3D game interpreter for LucasArts LUA-based 3D adventures."
+arch=('x86_64')
+license=('LGPL')
+url="http://www.residualvm.org/"
+depends=('sdl2' 'libmad' 'libmpeg2' 'libvorbis' 'hicolor-icon-theme'
+         'libjpeg-turbo' 'alsa-lib' 'glew' 'freetype2')
+optdepends=('fluidsynth: for MIDI SoundFont2 support')
+source=($pkgname-$pkgver.tar.gz::"https://github.com/residualvm/residualvm/archive/$pkgver.tar.gz")
+sha256sums=('515b02129dd374bc9c0b732ddeaaaa3a342cc25ea0ea3c4ccf19141b5d362e1d')
+
+build() {
+  cd "${srcdir}/$pkgname-$pkgver"
+  ./configure --disable-debug \
+              --enable-release \
+              --prefix=/usr
+  make
+}
+
+package() {
+  cd "${srcdir}/$pkgname-$pkgver"
+  make DESTDIR="$pkgdir" install
+  install -Dm644 "dists/$pkgname.desktop" "$pkgdir/usr/share/applications/$pkgname.desktop"
+  install -Dm644 "icons/$pkgname.png" "$pkgdir/usr/share/icons/hicolor/256x256/$pkgname.png"
+  install -Dm644 "icons/$pkgname-big.png" "$pkgdir/usr/share/icons/hicolor/512x512/$pkgname.png"
+}