PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): juergen <juergen@archlinux.org>
# Contributor (Arch): Manolis Tzanidakis, Petter Gundersen

# # I maintain this because:
# Arch version lacks additional optimization and hardening flags

pkgname=scummvm
pkgver=2.9.0
pkgrel=1
pkgdesc="A 'virtual machine' for several classic graphical point-and-click adventure games."
arch=('x86_64')
license=('GPL')
url="http://www.scummvm.org/"
depends=('libpng' 'libtheora' 'sdl2' 'sdl2_net' 'fluidsynth' 'flac' 'faad2' 'libvorbis' 'libmad' 'freetype2'
         'libgl' 'glu' 'libjpeg-turbo' 'libmpeg2' 'curl' 'a52dec' 'giflib' 'glew' 'libspeechd' 'gtk3' 'sndio')
makedepends=('mesa')
options=('!lto')
source=("https://downloads.scummvm.org/frs/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz")
sha512sums=('51236557f93052f2c6f840a135fa775ec4396cfbe618ee74259f29be7e0f0aa6b62d40920e3f03b92991794434ae44ef6f4a26a4615c5e27b362c1545e33b536')
b2sums=('bb9af6016e4849220b873f35f091d31b9648c3e87b3838f6b4605dc727d2a37687e1d8993218715f3579b400eb11a29c52671136e16fac86415fcbbb87f0c016')

build() {
  cd ${pkgname}-${pkgver}

  export CFLAGS="$CFLAGS -O3 -fPIE -flto=auto"
  export CXXFLAGS="$CXXFLAGS -O3 -fPIE -flto=auto"
  export LDFLAGS="$LDFLAGS,-pie"
  ./configure \
    --enable-release \
    --enable-all-engines \
    --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
}