PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): juergen <juergen@archlinux.org>
# Contributor (Arch): Manolis Tzanidakis, Petter Gundersen

# # I maintain this because:
# Arch version does not build all game engines
# Arch version lacks additional optimization and hardening flags

pkgname=scummvm
pkgver=2.5.0
pkgrel=2
pkgdesc="A 'virtual machine' for several classic graphical point-and-click adventure games."
arch=('x86_64')
license=('GPL')
url="http://www.scummvm.org/"
depends=('libpng' 'libtheora' 'sdl2' 'sdl2_net' 'fluidsynth' 'flac' 'faad2' 'libvorbis' 'libmad' 'freetype2'
         'libgl' 'glu' 'libjpeg-turbo' 'libmpeg2' 'curl' 'a52dec')
makedepends=('mesa')
source=("https://downloads.scummvm.org/frs/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz")
b2sums=('a5153280999e321be5bf7b56411c163d5ba1d4fb142fc900e1c3cb709d357d199d3764a94af57ab7218ee201bdbe6288adf222add9ffc941324b84d0e6954fe8')

build() {
  cd ${pkgname}-${pkgver}
  # -flto=4 breaks compilation
  export CFLAGS="$CFLAGS -O3 -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"
  ./configure \
    --enable-c++11 \
    --enable-release \
    --enable-all-engines \
    --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 dists/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
}