PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): juergen <juergen@archlinux.org>
# Contributor (Arch): Manolis Tzanidakis, Petter Gundersen

# # I maintain this because:
# Arch version does not build all game engines
# Arch version lacks additional optimization and hardening flags

pkgname=scummvm
pkgver=2.2.0
pkgrel=2
pkgdesc="A 'virtual machine' for several classic graphical point-and-click adventure games."
arch=('x86_64')
license=('GPL')
url="http://www.scummvm.org/"
depends=('libpng' 'libtheora' 'sdl2' 'sdl2_net' 'fluidsynth' 'flac' 'faad2' 'libvorbis' 'libmad' 'freetype2'
         'libgl' 'glu' 'libjpeg-turbo' 'libmpeg2' 'curl' 'a52dec')
makedepends=('mesa')
source=("https://downloads.scummvm.org/frs/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.xz"
        "${pkgname}-2.2.0-fluidsynth_loghandler.patch::https://github.com/scummvm/scummvm/pull/2729.patch"
        "${pkgname}-2.2.0-fluidsynth_loghandler_fix.patch::https://github.com/scummvm/scummvm/commit/a3bc5d64b8c4041326c8a214c47f9a206fb8b693.patch"
        "${pkgname}-2.2.0-fluidsynth2.0.patch::https://github.com/scummvm/scummvm/commit/6ef406ac20a68f53e66bb98a0c9842dc9553da07.patch"
        "${pkgname}-2.2.0-fluidsynth2.2.patch::https://github.com/scummvm/scummvm/pull/2915.patch")
b2sums=('b44a07d7ad6747b136465f81122464f02e5cc655c205d6f4424555311563f8ceaa8072972d05512af85d18fabba78d5ea9396ea314581776c1ef8d88ca6ab81b'
        '230c0b3dbd5b72772e72da40015b8ca23783dae547dfbab5597d46b43c3873799fb8b830d6926b88de29ec0e3f6da902e2315db7cc56d32cc488fc80eaf5bcfa'
        '17cd24ba5a6c6edfc3f8b7cc9e5eb5a7d1a3829549eab3770ec43f5e710c964e8a993260017ab0c482c91d059cca9a39fa0ac9037762a383e1d7575e8c2cb0f4'
        '0b9e4d7e49f5b60ecf00ab97b4e0074d1ad17c3044d5d01b0e49f44bd5131e9e14779d696cec7e920703fb273c0d86ff4b6871ec2aa6515720ac0cf2dd2414ae'
        'c5c1f438efb17d5cbb8cb48193d57dd324aca3fa03efe6c165f6689fd3f4daf9fa8c9d6239299c4c7c0e59f499ec0a295dd060a731c99b69cf1647898fd770a5')

prepare() {
  cd ${pkgname}-${pkgver}
  patch -Np1 -i ../${pkgname}-2.2.0-fluidsynth_loghandler.patch
  patch -Np1 -i ../${pkgname}-2.2.0-fluidsynth_loghandler_fix.patch
  patch -Np1 -i ../${pkgname}-2.2.0-fluidsynth2.0.patch
  patch -Np1 -i ../${pkgname}-2.2.0-fluidsynth2.2.patch
}
build() {
  cd ${pkgname}-${pkgver}
  # -flto=4 breaks compilation
  export CFLAGS="$CFLAGS -O3 -fPIE"
  export CXXFLAGS="$CXXFLAGS -O3 -fPIE"
  export LDFLAGS="$LDFLAGS,-pie"
  ./configure \
    --enable-all-engines \
    --enable-c++11 \
    --enable-release \
    --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 dists/${pkgname}.desktop "${pkgdir}"/usr/share/applications/${pkgname}.desktop
}