PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): Lone_Wolf <lonewolf@xs4all.nl> 
# Contributor (Arch): sausageandeggs <s_stoakley at hotmail.co.uk>

# # I maintain this because:
# Arch version desktop file points to raw executable

pkgname=singularity
pkgver=0.30c
_pkgver=007
pkgrel=9.2
pkgdesc="Strategy game - simulation of true AI"
arch=('any')
url="http://emhsoft.com/singularity/index.html"
license=('GPL2' 'custom')
depends=('python2' 'python2-pygame' 'sdl_image' 'sdl_mixer' 'python2-numpy')
source=("http://www.emhsoft.com/singularity/${pkgname}-${pkgver}-src.tar.gz"
        "${pkgname}-music-${_pkgver}.zip::http://www.emhsoft.com/singularity/endgame-${pkgname}-music-${_pkgver}.zip"
        "singularity"
        "singularity.desktop")
sha512sums=('ffca50c179b745561a25e3fb3525abb862d72f63f533f8a41472067d0ce94c8a236486c9c40a5040335d84e903c498805d591dc546a92d0a7651105103fe114f'
            'ab46e77c833085f0c5b1b46fef72ab807e79ca422ad043ef67a4bf4384cb0177319f21b4bd01496e6c3fc6fe9a2f36ec256e19f0e829ad7bf9f0c5bd38bf0fe5'
            '30710a6b7cc78f3e341d6b32a632f3e1f76cdc513b481226b710612d47611cccb037b35fdfc3d2a564b8d16683e2b6bec307e1c3cbf3d830dc90d85d821ad049'
            '4ec21b1846f38565e1f1227d571bf2b23c97f6fd3cd3bb4267a43e5c4e901dbd1bd86c3a08c61810e34e9a0113a2437932d765dea155614c6fc91d8efb8c64e5')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  sed -i 's|/usr/bin/env python|/usr/bin/env python2|g' "code/singularity.py"

  find . -name \*.pyc -delete
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # install game
  install -Dm644 singularity.py ${pkgdir}/usr/share/singularity/singularity.py
  cp -R code data "${pkgdir}/usr/share/${pkgname}"
  cp -R "${srcdir}/endgame-${pkgname}-music-${_pkgver}" "${pkgdir}/usr/share/${pkgname}/music"

  # install shell script
  install -Dm755 "${srcdir}/singularity" "${pkgdir}/usr/bin/singularity"

  # desktop file
  install -Dm644 "${srcdir}/singularity.desktop" "${pkgdir}/usr/share/applications/singularity.desktop"
  install -Dm644 "${pkgdir}/usr/share/singularity/data/images/icon.png" "${pkgdir}/usr/share/pixmaps/$pkgname.png"

  # license: code is GPL2, but data & music fall under other licenses
  install -Dm644 README.txt "${pkgdir}/usr/share/doc/${pkgname}/README.txt"
  install -d "${pkgdir}/usr/share/licenses/${pkgname}/"
  cd "${pkgdir}/usr/share/licenses/${pkgname}/"
  ln -s ../../doc/${pkgname}/README.txt .

  python2 -m compileall "${pkgdir}/usr/share/${pkgname}"
  python2 -O -m compileall "${pkgdir}/usr/share/${pkgname}"
}