PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (Arch): Sven-Hendrik Haase <svenstaro@gmail.com>
# Contributor (Arch): Lone_Wolf <lonewolf@xs4all.nl>
# Contributor (Arch): sausageandeggs <s_stoakley at hotmail.co.uk>

# # I maintain this because:
# Arch version desktop file points to raw executable
# Arch version does not name the music archive

pkgname=singularity
pkgver=1.00
_musicver=025e2696638bcc3bf7690679c3a17c0b46823bbe
pkgrel=2
pkgdesc="Endgame: Singularity - simulation of true AI"
arch=('any')
url="http://emhsoft.com/singularity/index.html"
license=('GPL2' 'custom')
depends=('python' 'python-pygame' 'python-numpy')
makedepends=('python-setuptools')
source=("https://github.com/singularity/singularity/releases/download/v${pkgver}/singularity-${pkgver}.tar.gz"{,.asc}
        singularity-music-${_musicver}.tar.gz::https://github.com/singularity/singularity-music/archive/${_musicver}.tar.gz
        "singularity.desktop")
validpgpkeys=('B3131A451DBFDF7CA05B4197054BBB9F7D806442')
b2sums=('1ca2b120311a19f175014835930610583e8f605dbda3ca3ca96d7e0da86bddeb4b0a264f50a003aa51e05b86ce971255ffda5f498598dde6be370b9a953eb1d0'
        'SKIP'
        '328988697e6a630b7640fa2076fa53ffe5a7c4a3fe4772de6c2ffc4ece3081de4bb57de51159b3ad51f2e54bf796d3775bc40a802e43315aec7767630f8e580f'
        '7beb5be09e33fbd7caa655221ff6b2bced2c1b92685fd709f9c44cabad962cd2884e0f39fd61827e8272c62115be5dfd2444753d7e337a63e142eb8d787c2f5a')

prepare() {
  cd "$pkgname-$pkgver"

  mv "$srcdir"/singularity-music-${_musicver} singularity/music
  sed -i "s|prune|recursive-include singularity/music *|g" MANIFEST.in
}

build() {
  cd "$pkgname-$pkgver"

  python setup.py build
}

package() {
  cd "$pkgname-$pkgver"

  python setup.py install --prefix=/usr --root="$pkgdir" --optimize=1
  mv run_singularity.sh "$pkgdir"/usr/bin/singularity

  install -Dm644 "$srcdir/singularity.desktop" "$pkgdir/usr/share/applications/singularity.desktop"
  install -Dm644 -t "$pkgdir"/usr/share/licenses/$pkgname LICENSE.cc0.txt LICENSE.CC-BY-SA-3.txt LICENSE.gpl.txt LICENSE.txt
}