blob: 7e5bc3171ce4eaa5a2fd7eac5f9f2fb302351980 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
|
# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Maintainer (AUR): Harms <thotro at lyse dot net>
# Contributor (AUR): Pascal Grossé <pascal.grosse@gmail.com>
# # I maintain this because:
# AUR version uses /opt
# AUR version uses http
# AUR version uses debug build
# AUR version lacks glext patch
# AUR version does not use -O3
# AUR version lacks offline patch
# AUR version lacks DLC
pkgname=tome4
pkgver=1.5.10
pkgrel=4
_ashesver=1.0.6
_orcsver=1.0.4
_cultsver=1.0.1
pkgdesc="An open-source, single-player, role-playing roguelike game set in the world of Eyal."
pkgdesc+="Includes DLC and offline patch."
arch=('i686' 'x86_64')
url="https://te4.org/"
license=('custom' 'GPL3')
depends=(glu openal libvorbis sdl2_ttf sdl2_image)
makedepends=(premake zip unzip)
options=(!makeflags emptydirs)
source=("${url}dl/t-engine/t-engine4-src-${pkgver}.tar.bz2"
sdl2-path-fix.patch
glext-include-removal.patch
O3-support.patch
offline-donator.patch
ashes-urhrok_${_ashesver}.teaac
orcs_${_orcsver}.teaac
cults_${_cultsver}.teaac
tome4
tome4.desktop)
conflicts=('tome4-beta' 'tome4-git' 'tome4-nomusic')
sha512sums=('852ead36d705fe1cee834f33a3cbaf7841d991bc03fdedd0740e7c5ddbd9979f4fdcdd2bf951bf4d666229f65b2010c385128bf07717c05b1b0b91319cbff32e'
'bbe96647c738eea46e52ed26c0d404f0daf14c6c367d005a23c88026665ed2eba207fd99ef81e14e4cd740108360d3be176158585790d8c55389e3ffdf160e29'
'22344a867a06ec9d1739acbbf3e5ac20d9e17ed7bcfc28bdb873e0f3ba4953d7639ebb27a7513776bc2078276207c3ebbec1b15e96cb5ea3e2638bd345863439'
'790dce2ee4f42f0bdb536eed464f2f9849039852249deb1de06f2e71e2938cb70380ad6b617900b4b159f60060a4163a37583e3c1639578b090cc77621243477'
'8847d6ed5a505ae4dd4399d88e3e2a839afdf589895662ab61f0fec0b475130a9088489f5dab5b5e7ce8e79968771227fd73abf5c71521da559d4187f200e3c7'
'842b0de3a6d98f9cb575404e2a11799c5117e96d957289f7336c6c8e92df665e9c6affc30653a3a1f4e3618efde9a3168a08e0c2989380f1fd170cc243568fd1'
'709da5f7083800172d64d1a7beb187887e108f929bc47209db178fc2ea58fe5021b711239a8713719c68431def56a53c9521fecb0a528f820318344fb3ef30ea'
'd23ee192c4cc3ca53dbbed41815f867927e027d7c8b3a71d136a977ef92e1b56214e6da1e24ef3b7a5ac0ebd4e61fdafff32dba0060bd1b9f1d8c430f206ea05'
'521e99b07082d6379606541f625f68fa666610e1c3f27e5e4803cc44bc16e60f28824792d1b13e477a08176f609288e693be3d92ba60cb4fea343f11854fe466'
'94ed400247d4137fc4f6e770e724a47a028a2fafff15c38ba952d828db4d3890e13ae2c51b8cf9e070b545ba07e5c183b44c15886480b1e06d3c94a2826e5c73')
###############################################################################
# 1. Patch the game.
###############################################################################
prepare() {
cd "$srcdir"/t-engine4-src-${pkgver}
patch -p1 -i "${srcdir}/sdl2-path-fix.patch"
patch -p1 -i "${srcdir}/glext-include-removal.patch"
patch -p1 -i "${srcdir}/O3-support.patch"
patch -p1 -i "${srcdir}/offline-donator.patch"
cp "${srcdir}/ashes-urhrok_${_ashesver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/ashes-urhrok.teaac"
cp "${srcdir}/orcs_${_orcsver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/orcs.teaac"
cp "${srcdir}/cults_${_cultsver}.teaac" "${srcdir}/t-engine4-src-${pkgver}/game/addons/cults.teaac"
}
###############################################################################
# 2. Build the game engine from source.
###############################################################################
build() {
cd t-engine4-src-${pkgver}
premake4 gmake
make -j4 config=release
}
###############################################################################
# 3. Create the package. Copy all that shall be installed into the package dir.
###############################################################################
package() {
# Extract and install the icon.
unzip -oj -qq "${srcdir}/t-engine4-src-${pkgver}/game/engines/te4-${pkgver}.teae" \
"data/gfx/te4-icon.png" -d "${srcdir}"
install -Dm644 "${srcdir}/te4-icon.png" "${pkgdir}/usr/share/pixmaps/${pkgname}.png"
# Install the documents.
install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CONTRIBUTING" "${pkgdir}/usr/share/doc/${pkgname}/CONTRIBUTING"
install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/CREDITS" "${pkgdir}/usr/share/doc/${pkgname}/CREDITS"
# Install the custom license into standard location.
install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
install -Dm644 "${srcdir}/t-engine4-src-${pkgver}/COPYING-MEDIA" "${pkgdir}/usr/share/licenses/${pkgname}/COPYING-MEDIA"
# Install the game executable, and the launcher.
install -Dm755 "${srcdir}/t-engine4-src-${pkgver}/t-engine" "${pkgdir}/usr/lib/${pkgname}/t-engine"
install -Dm755 "${srcdir}/${pkgname}" "${pkgdir}/usr/bin/${pkgname}"
install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
# Install the game data.
cp -r "${srcdir}/t-engine4-src-${pkgver}/bootstrap" "${pkgdir}/usr/lib/${pkgname}/"
cp -r "${srcdir}/t-engine4-src-${pkgver}/game" "${pkgdir}/usr/lib/${pkgname}/"
}
|
