1 files changed, 51 insertions, 0 deletions
diff --git a/PKGBUILD b/PKGBUILD
new file mode 100644
index 0000000..e6dab82
--- /dev/null
+++ b/PKGBUILD
@@ -0,0 +1,51 @@
+# Maintainer: jc_gargma <jc_gargma@iserlohn-fortress.net>
+# Maintainer (AUR): Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor (AUR): Jack Mitchell <jack@embed.me.uk>
+# Contributor (AUR): Kevin MacMartin <prurigro at gmail dot com>
+
+# # I maintain this because:
+# AUR version not configured for OpenRC
+
+pkgname=xboxdrv
+pkgver=0.8.8
+pkgrel=4
+pkgdesc='Userspace gamepad driver for Linux'
+url='http://pingus.seul.org/~grumbel/xboxdrv'
+arch=('i686' 'x86_64')
+license=('GPL3')
+depends=('libx11' 'dbus-glib' 'libusb' 'python2-dbus' 'eudev')
+makedepends=('scons' 'boost' 'pkg-config' 'libx11' 'python')
+backup=("etc/default/xboxdrv")
+source=(${pkgname}-${pkgver}.tar.gz::https://github.com/xboxdrv/${pkgname}/archive/v${pkgver}.tar.gz
+        xboxdrv.default
+        fix-60-sec-delay.patch
+        scons-py3.patch)
+sha512sums=('3f27856da211a14e27a84fa5919da7965262adc36da16c75eed9bae891098183b5751a3e707573b4ab64e69096ea74d455e8f64827c88b38b65af94cc13b34ad'
+            '4f6e9a12b208254e19daba477dd7787147a8b2c8a83007d92f8cfce6212c21ce3306f23a2669080f0e46986ca102ab08c262b42c678caf1a891326b4e2c40b5f'
+            '58170b3f96f02e5ba0af5f6641482fb1c612ca70650e475d68b55c05a62ec0831033190b90e591d593fd6b25c2a155e6c4975f37eef1534245947156a5e3285f'
+            'b3a3bbb51fa1c4ad4dd898136c3bf7c0f13193bdd07bbcb5c8243edb747c68223fe8c5bd2fd578f6c2b18844827524abb0533ce98b6e0e60fe936597cdba811d')
+
+prepare() {
+  cd ${pkgname}-${pkgver}
+  sed 's|python|python2|g' -i examples/*.py
+  patch -p1 < "${srcdir}/fix-60-sec-delay.patch"
+  # activate this patch when scons gets switched back to py3
+  # patch -p1 < "${srcdir}/scons-py3.patch"
+}
+
+build() {
+  cd ${pkgname}-${pkgver}
+  scons \
+    LINKFLAGS="${LDFLAGS}" \
+    CXXFLAGS="${CPPFLAGS} ${CXXFLAGS}" \
+    "${MAKEFLAGS}"
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  make PREFIX=/usr DESTDIR="${pkgdir}" install
+  install -Dm 644 "${srcdir}/${pkgname}.default" "${pkgdir}/etc/default/${pkgname}"
+  install -Dm 644 README.md NEWS PROTOCOL -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 examples/* -t "${pkgdir}/usr/share/doc/${pkgname}/examples"
+  install -Dm 644 data/org.seul.Xboxdrv.conf -t "${pkgdir}/etc/dbus-1/system.d"
+}